\section{NAME\label{NAME-perldsc}}


perldsc - Perl Data Structures Cookbook

\section{DESCRIPTION\label{DESCRIPTION-perldsc}\index{description of the Perl
    Data Stuctures Cookbook}}


The single feature most sorely lacking in the Perl programming language
prior to its 5.0 release was complex data structures.  Even without direct
language support, some valiant programmers did manage to emulate them, but
it was hard work and not for the faint of heart.  You could occasionally
get away with the \texttt{\$m\{\$AoA,\$b\}} notation borrowed from \textbf{awk} in which the
keys are actually more like a single concatenated string \texttt{"\$AoA\$b"}, but
traversal and sorting were difficult.  More desperate programmers even
hacked Perl's internal symbol table directly, a strategy that proved hard
to develop and maintain--to put it mildly.



The 5.0 release of Perl let us have complex data structures.  You
may now write something like this and all of a sudden, you'd have an array
with three dimensions!

\begin{verbatim}
    for $x (1 .. 10) {
        for $y (1 .. 10) {
            for $z (1 .. 10) {
                $AoA[$x][$y][$z] =
                    $x ** $y + $z;
            }
        }
    }
\end{verbatim}


Alas, however simple this may appear, underneath it's a much more
elaborate construct than meets the eye!



How do you print it out?  Why can't you say just \texttt{print @AoA}?  How do
you sort it?  How can you pass it to a function or get one of these back
from a function?  Is it an object?  Can you save it to disk to read
back later?  How do you access whole rows or columns of that matrix?  Do
all the values have to be numeric?



As you see, it's quite easy to become confused.  While some small portion
of the blame for this can be attributed to the reference-based
implementation, it's really more due to a lack of existing documentation with
examples designed for the beginner.



This document is meant to be a detailed but understandable treatment of the
many different sorts of data structures you might want to develop.  It
should also serve as a cookbook of examples.  That way, when you need to
create one of these complex data structures, you can just pinch, pilfer, or
purloin a drop-in example from here.



Let's look at each of these possible constructs in detail.  There are separate
sections on each of the following:

\begin{itemize}

\item arrays of arrays
\item hashes of arrays
\item arrays of hashes
\item hashes of hashes
\item more elaborate constructs\end{itemize}


But for now, let's look at general issues common to all
these types of data structures.

\section{REFERENCES\label{REFERENCES}\index{references}}


The most important thing to understand about all data structures in Perl
-- including multidimensional arrays--is that even though they might
appear otherwise, Perl \texttt{@ARRAY}s and \texttt{\%HASH}es are all internally
one-dimensional.  They can hold only scalar values (meaning a string,
number, or a reference).  They cannot directly contain other arrays or
hashes, but instead contain \textit{references} to other arrays or hashes.



You can't use a reference to an array or hash in quite the same way that you
would a real array or hash.  For C or C++ programmers unused to
distinguishing between arrays and pointers to the same, this can be
confusing.  If so, just think of it as the difference between a structure
and a pointer to a structure.



You can (and should) read more about references in the perlref(1) man
page.  Briefly, references are rather like pointers that know what they
point to.  (Objects are also a kind of reference, but we won't be needing
them right away--if ever.)  This means that when you have something which
looks to you like an access to a two-or-more-dimensional array and/or hash,
what's really going on is that the base type is
merely a one-dimensional entity that contains references to the next
level.  It's just that you can \textit{use} it as though it were a
two-dimensional one.  This is actually the way almost all C
multidimensional arrays work as well.

\begin{verbatim}
    $array[7][12]                       # array of arrays
    $array[7]{string}                   # array of hashes
    $hash{string}[7]                    # hash of arrays
    $hash{string}{'another string'}     # hash of hashes
\end{verbatim}


Now, because the top level contains only references, if you try to print
out your array in with a simple print() function, you'll get something
that doesn't look very nice, like this:

\begin{verbatim}
    @AoA = ( [2, 3], [4, 5, 7], [0] );
    print $AoA[1][2];
  7
    print @AoA;
  ARRAY(0x83c38)ARRAY(0x8b194)ARRAY(0x8b1d0)
\end{verbatim}%$


That's because Perl doesn't (ever) implicitly dereference your variables.
If you want to get at the thing a reference is referring to, then you have
to do this yourself using either prefix typing indicators, like
\texttt{\$\{\$blah\}}, \texttt{@\{\$blah\}}, \texttt{@\{\$blah[\$i]\}}, or else postfix pointer arrows,
like \texttt{\$a-$>$[3]}, \texttt{\$h-$>$\{fred\}}, or even \texttt{\$ob-$>$method()-$>$[3]}.

\section{COMMON MISTAKES\label{COMMON_MISTAKES}\index{common mistakes
    with data structures}}


The two most common mistakes made in constructing something like
an array of arrays is either accidentally counting the number of
elements or else taking a reference to the same memory location
repeatedly.  Here's the case where you just get the count instead
of a nested array:

\begin{verbatim}
    for $i (1..10) {
        @array = somefunc($i);
        $AoA[$i] = @array;      # WRONG!
    }
\end{verbatim}


That's just the simple case of assigning an array to a scalar and getting
its element count.  If that's what you really and truly want, then you
might do well to consider being a tad more explicit about it, like this:

\begin{verbatim}
    for $i (1..10) {
        @array = somefunc($i);
        $counts[$i] = scalar @array;
    }
\end{verbatim}


Here's the case of taking a reference to the same memory location
again and again:

\begin{verbatim}
    for $i (1..10) {
        @array = somefunc($i);
        $AoA[$i] = \@array;     # WRONG!
    }
\end{verbatim}


So, what's the big problem with that?  It looks right, doesn't it?
After all, I just told you that you need an array of references, so by
golly, you've made me one!



Unfortunately, while this is true, it's still broken.  All the references
in @AoA refer to the \textit{very same place}, and they will therefore all hold
whatever was last in @array!  It's similar to the problem demonstrated in
the following C program:

\begin{verbatim}
    #include <pwd.h>
    main() {
        struct passwd *getpwnam(), *rp, *dp;
        rp = getpwnam("root");
        dp = getpwnam("daemon");
\end{verbatim}
\begin{verbatim}
        printf("daemon name is %s\nroot name is %s\n",
                dp->pw_name, rp->pw_name);
    }
\end{verbatim}


Which will print

\begin{verbatim}
    daemon name is daemon
    root name is daemon
\end{verbatim}


The problem is that both \texttt{rp} and \texttt{dp} are pointers to the same location
in memory!  In C, you'd have to remember to malloc() yourself some new
memory.  In Perl, you'll want to use the array constructor \texttt{[]} or the
hash constructor \texttt{\{\}} instead.   Here's the right way to do the preceding
broken code fragments:

\begin{verbatim}
    for $i (1..10) {
        @array = somefunc($i);
        $AoA[$i] = [ @array ];
    }
\end{verbatim}


The square brackets make a reference to a new array with a \textit{copy}
of what's in @array at the time of the assignment.  This is what
you want.



Note that this will produce something similar, but it's
much harder to read:

\begin{verbatim}
    for $i (1..10) {
        @array = 0 .. $i;
        @{$AoA[$i]} = @array;
    }
\end{verbatim}


Is it the same?  Well, maybe so--and maybe not.  The subtle difference
is that when you assign something in square brackets, you know for sure
it's always a brand new reference with a new \textit{copy} of the data.
Something else could be going on in this new case with the \texttt{@\{\$AoA[\$i]\}\}}
dereference on the left-hand-side of the assignment.  It all depends on
whether \texttt{\$AoA[\$i]} had been undefined to start with, or whether it
already contained a reference.  If you had already populated @AoA with
references, as in

\begin{verbatim}
    $AoA[3] = \@another_array;
\end{verbatim}%$


Then the assignment with the indirection on the left-hand-side would
use the existing reference that was already there:

\begin{verbatim}
    @{$AoA[3]} = @array;
\end{verbatim}%$


Of course, this \textit{would} have the "interesting" effect of clobbering
@another\_array.  (Have you ever noticed how when a programmer says
something is "interesting", that rather than meaning "intriguing",
they're disturbingly more apt to mean that it's "annoying",
"difficult", or both?  :-)



So just remember always to use the array or hash constructors with \texttt{[]}
or \texttt{\{\}}, and you'll be fine, although it's not always optimally
efficient.



Surprisingly, the following dangerous-looking construct will
actually work out fine:

\begin{verbatim}
    for $i (1..10) {
        my @array = somefunc($i);
        $AoA[$i] = \@array;
    }
\end{verbatim}


That's because my() is more of a run-time statement than it is a
compile-time declaration \textit{per se}.  This means that the my() variable is
remade afresh each time through the loop.  So even though it \textit{looks} as
though you stored the same variable reference each time, you actually did
not!  This is a subtle distinction that can produce more efficient code at
the risk of misleading all but the most experienced of programmers.  So I
usually advise against teaching it to beginners.  In fact, except for
passing arguments to functions, I seldom like to see the gimme-a-reference
operator (backslash) used much at all in code.  Instead, I advise
beginners that they (and most of the rest of us) should try to use the
much more easily understood constructors \texttt{[]} and \texttt{\{\}} instead of
relying upon lexical (or dynamic) scoping and hidden reference-counting to
do the right thing behind the scenes.



In summary:

\begin{verbatim}
    $AoA[$i] = [ @array ];      # usually best
    $AoA[$i] = \@array;         # perilous; just how my() was that array?
    @{ $AoA[$i] } = @array;     # way too tricky for most programmers
\end{verbatim}
\section{CAVEAT ON PRECEDENCE\label{CAVEAT_ON_PRECEDENCE}\index{caveat on precedence}}


Speaking of things like \texttt{@\{\$AoA[\$i]\}}, the following are actually the
same thing:

\begin{verbatim}
    $aref->[2][2]       # clear
    $$aref[2][2]        # confusing
\end{verbatim}


That's because Perl's precedence rules on its five prefix dereferencers
(which look like someone swearing: \texttt{\$ @ * \% \&}) make them bind more
tightly than the postfix subscripting brackets or braces!  This will no
doubt come as a great shock to the C or C++ programmer, who is quite
accustomed to using \texttt{*a[i]} to mean what's pointed to by the \textit{i'th}
element of \texttt{a}.  That is, they first take the subscript, and only then
dereference the thing at that subscript.  That's fine in C, but this isn't C.



The seemingly equivalent construct in Perl, \texttt{\$\$aref[\$i]} first does
the deref of \$aref, making it take \$aref as a reference to an
array, and then dereference that, and finally tell you the \textit{i'th} value
of the array pointed to by \$AoA. If you wanted the C notion, you'd have to
write \texttt{\$\{\$AoA[\$i]\}} to force the \texttt{\$AoA[\$i]} to get evaluated first
before the leading \texttt{\$} dereferencer.

\section{WHY YOU SHOULD ALWAYS \texttt{use strict}\label{WHY_YOU_SHOULD_ALWAYS_use_strict}\index{WHY YOU SHOULD ALWAYS use strict}}


If this is starting to sound scarier than it's worth, relax.  Perl has
some features to help you avoid its most common pitfalls.  The best
way to avoid getting confused is to start every program like this:

\begin{verbatim}
    #!/usr/bin/perl -w
    use strict;
\end{verbatim}


This way, you'll be forced to declare all your variables with my() and
also disallow accidental "symbolic dereferencing".  Therefore if you'd done
this:

\begin{verbatim}
    my $aref = [
        [ "fred", "barney", "pebbles", "bambam", "dino", ],
        [ "homer", "bart", "marge", "maggie", ],
        [ "george", "jane", "elroy", "judy", ],
    ];
\end{verbatim}
\begin{verbatim}
    print $aref[2][2];
\end{verbatim}


The compiler would immediately flag that as an error \textit{at compile time},
because you were accidentally accessing \texttt{@aref}, an undeclared
variable, and it would thereby remind you to write instead:

\begin{verbatim}
    print $aref->[2][2]
\end{verbatim}%$

\section{DEBUGGING\label{DEBUGGING}\index{debugging}}


Before version 5.002, the standard Perl debugger didn't do a very nice job of
printing out complex data structures.  With 5.002 or above, the
debugger includes several new features, including command line editing as
well as the \texttt{x} command to dump out complex data structures.  For
example, given the assignment to \$AoA above, here's the debugger output:

\begin{verbatim}
    DB<1> x $AoA
    $AoA = ARRAY(0x13b5a0)
       0  ARRAY(0x1f0a24)
          0  'fred'
          1  'barney'
          2  'pebbles'
          3  'bambam'
          4  'dino'
       1  ARRAY(0x13b558)
          0  'homer'
          1  'bart'
          2  'marge'
          3  'maggie'
       2  ARRAY(0x13b540)
          0  'george'
          1  'jane'
          2  'elroy'
          3  'judy'
\end{verbatim}
\section{CODE EXAMPLES\label{CODE_EXAMPLES}\index{code examples of
    data structures}}


Presented with little comment (these will get their own manpages someday)
here are short code examples illustrating access of various
types of data structures.

\section{ARRAYS OF ARRAYS\label{ARRAYS_OF_ARRAYS}\index{ARRAYS OF ARRAYS}}
\subsection*{Declaration of an ARRAY OF ARRAYS\label{Declaration_of_an_ARRAY_OF_ARRAYS}\index{Declaration of an ARRAY OF ARRAYS}}
\begin{verbatim}
 @AoA = (
        [ "fred", "barney" ],
        [ "george", "jane", "elroy" ],
        [ "homer", "marge", "bart" ],
      );
\end{verbatim}
\subsection*{Generation of an ARRAY OF ARRAYS\label{Generation_of_an_ARRAY_OF_ARRAYS}\index{Generation of an ARRAY OF ARRAYS}}
\begin{verbatim}
 # reading from file
 while ( <> ) {
     push @AoA, [ split ];
 }
\end{verbatim}
\begin{verbatim}
 # calling a function
 for $i ( 1 .. 10 ) {
     $AoA[$i] = [ somefunc($i) ];
 }
\end{verbatim}
\begin{verbatim}
 # using temp vars
 for $i ( 1 .. 10 ) {
     @tmp = somefunc($i);
     $AoA[$i] = [ @tmp ];
 }
\end{verbatim}
\begin{verbatim}
 # add to an existing row
 push @{ $AoA[0] }, "wilma", "betty";
\end{verbatim}

\subsection*{Access and Printing of an ARRAY OF ARRAYS\label{Access_and_Printing_of_an_ARRAY_OF_ARRAYS}\index{access and printing of an array of arrays}}
\begin{verbatim}
 # one element
 $AoA[0][0] = "Fred";
\end{verbatim}
\begin{verbatim}
 # another element
 $AoA[1][1] =~ s/(\w)/\u$1/;
\end{verbatim}
\begin{verbatim}
 # print the whole thing with refs
 for $aref ( @AoA ) {
     print "\t [ @$aref ],\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing with indices
 for $i ( 0 .. $#AoA ) {
     print "\t [ @{$AoA[$i]} ],\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing one at a time
 for $i ( 0 .. $#AoA ) {
     for $j ( 0 .. $#{ $AoA[$i] } ) {
         print "elt $i $j is $AoA[$i][$j]\n";
     }
 }
\end{verbatim}
\section{HASHES OF ARRAYS\label{HASHES_OF_ARRAYS}\index{HASHES OF ARRAYS}}
\subsection*{Declaration of a HASH OF ARRAYS\label{Declaration_of_a_HASH_OF_ARRAYS}\index{declaration of a hash of arrays}}
\begin{verbatim}
 %HoA = (
        flintstones        => [ "fred", "barney" ],
        jetsons            => [ "george", "jane", "elroy" ],
        simpsons           => [ "homer", "marge", "bart" ],
      );
\end{verbatim}
\subsection*{Generation of a HASH OF ARRAYS\label{Generation_of_a_HASH_OF_ARRAYS}\index{Generation of a HASH OF ARRAYS}}
\begin{verbatim}
 # reading from file
 # flintstones: fred barney wilma dino
 while ( <> ) {
     next unless s/^(.*?):\s*//;
     $HoA{$1} = [ split ];
 }
\end{verbatim}
\begin{verbatim}
 # reading from file; more temps
 # flintstones: fred barney wilma dino
 while ( $line = <> ) {
     ($who, $rest) = split /:\s*/, $line, 2;
     @fields = split ' ', $rest;
     $HoA{$who} = [ @fields ];
 }
\end{verbatim}
\begin{verbatim}
 # calling a function that returns a list
 for $group ( "simpsons", "jetsons", "flintstones" ) {
     $HoA{$group} = [ get_family($group) ];
 }
\end{verbatim}
\begin{verbatim}
 # likewise, but using temps
 for $group ( "simpsons", "jetsons", "flintstones" ) {
     @members = get_family($group);
     $HoA{$group} = [ @members ];
 }
\end{verbatim}
\begin{verbatim}
 # append new members to an existing family
 push @{ $HoA{"flintstones"} }, "wilma", "betty";
\end{verbatim}
\subsection*{Access and Printing of a HASH OF ARRAYS\label{Access_and_Printing_of_a_HASH_OF_ARRAYS}\index{access and printing of a hash of arrays}}
\begin{verbatim}
 # one element
 $HoA{flintstones}[0] = "Fred";
\end{verbatim}
\begin{verbatim}
 # another element
 $HoA{simpsons}[1] =~ s/(\w)/\u$1/;
\end{verbatim}
\begin{verbatim}
 # print the whole thing
 foreach $family ( keys %HoA ) {
     print "$family: @{ $HoA{$family} }\n"
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing with indices
 foreach $family ( keys %HoA ) {
     print "family: ";
     foreach $i ( 0 .. $#{ $HoA{$family} } ) {
         print " $i = $HoA{$family}[$i]";
     }
     print "\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing sorted by number of members
 foreach $family ( sort { @{$HoA{$b}} <=> @{$HoA{$a}} } keys %HoA ) {
     print "$family: @{ $HoA{$family} }\n"
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing sorted by number of members and name
 foreach $family ( sort {
                            @{$HoA{$b}} <=> @{$HoA{$a}}
                                        ||
                                    $a cmp $b
            } keys %HoA )
 {
     print "$family: ", join(", ", sort @{ $HoA{$family} }), "\n";
 }
\end{verbatim}
\section{ARRAYS OF HASHES\label{ARRAYS_OF_HASHES}\index{ARRAYS OF HASHES}}
\subsection*{Declaration of an ARRAY OF HASHES\label{Declaration_of_an_ARRAY_OF_HASHES}\index{declaration of an array of hashes}}
\begin{verbatim}
 @AoH = (
        {
            Lead     => "fred",
            Friend   => "barney",
        },
        {
            Lead     => "george",
            Wife     => "jane",
            Son      => "elroy",
        },
        {
            Lead     => "homer",
            Wife     => "marge",
            Son      => "bart",
        }
  );
\end{verbatim}
\subsection*{Generation of an ARRAY OF HASHES\label{Generation_of_an_ARRAY_OF_HASHES}\index{Generation of an ARRAY OF HASHES}}
\begin{verbatim}
 # reading from file
 # format: LEAD=fred FRIEND=barney
 while ( <> ) {
     $rec = {};
     for $field ( split ) {
         ($key, $value) = split /=/, $field;
         $rec->{$key} = $value;
     }
     push @AoH, $rec;
 }
\end{verbatim}
\begin{verbatim}
 # reading from file
 # format: LEAD=fred FRIEND=barney
 # no temp
 while ( <> ) {
     push @AoH, { split /[\s+=]/ };
 }
\end{verbatim}
\begin{verbatim}
 # calling a function  that returns a key/value pair list, like
 # "lead","fred","daughter","pebbles"
 while ( %fields = getnextpairset() ) {
     push @AoH, { %fields };
 }
\end{verbatim}
\begin{verbatim}
 # likewise, but using no temp vars
 while (<>) {
     push @AoH, { parsepairs($_) };
 }
\end{verbatim}
\begin{verbatim}
 # add key/value to an element
 $AoH[0]{pet} = "dino";
 $AoH[2]{pet} = "santa's little helper";
\end{verbatim}
\subsection*{Access and Printing of an ARRAY OF HASHES\label{Access_and_Printing_of_an_ARRAY_OF_HASHES}\index{access and printing of an array of hashes}}
\begin{verbatim}
 # one element
 $AoH[0]{lead} = "fred";
\end{verbatim}
\begin{verbatim}
 # another element
 $AoH[1]{lead} =~ s/(\w)/\u$1/;
\end{verbatim}
\begin{verbatim}
 # print the whole thing with refs
 for $href ( @AoH ) {
     print "{ ";
     for $role ( keys %$href ) {
         print "$role=$href->{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing with indices
 for $i ( 0 .. $#AoH ) {
     print "$i is { ";
     for $role ( keys %{ $AoH[$i] } ) {
         print "$role=$AoH[$i]{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing one at a time
 for $i ( 0 .. $#AoH ) {
     for $role ( keys %{ $AoH[$i] } ) {
         print "elt $i $role is $AoH[$i]{$role}\n";
     }
 }
\end{verbatim}
\section{HASHES OF HASHES\label{HASHES_OF_HASHES}\index{HASHES OF HASHES}}
\subsection*{Declaration of a HASH OF HASHES\label{Declaration_of_a_HASH_OF_HASHES}\index{declaration of a hash of hashes}}
\begin{verbatim}
 %HoH = (
        flintstones => {
                lead      => "fred",
                pal       => "barney",
        },
        jetsons     => {
                lead      => "george",
                wife      => "jane",
                "his boy" => "elroy",
        },
        simpsons    => {
                lead      => "homer",
                wife      => "marge",
                kid       => "bart",
        },
 );
\end{verbatim}
\subsection*{Generation of a HASH OF HASHES\label{Generation_of_a_HASH_OF_HASHES}\index{generation of a hash of hashes}}
\begin{verbatim}
 # reading from file
 # flintstones: lead=fred pal=barney wife=wilma pet=dino
 while ( <> ) {
     next unless s/^(.*?):\s*//;
     $who = $1;
     for $field ( split ) {
         ($key, $value) = split /=/, $field;
         $HoH{$who}{$key} = $value;
     }
\end{verbatim}
\begin{verbatim}
 # reading from file; more temps
 while ( <> ) {
     next unless s/^(.*?):\s*//;
     $who = $1;
     $rec = {};
     $HoH{$who} = $rec;
     for $field ( split ) {
         ($key, $value) = split /=/, $field;
         $rec->{$key} = $value;
     }
 }
\end{verbatim}
\begin{verbatim}
 # calling a function  that returns a key,value hash
 for $group ( "simpsons", "jetsons", "flintstones" ) {
     $HoH{$group} = { get_family($group) };
 }
\end{verbatim}
\begin{verbatim}
 # likewise, but using temps
 for $group ( "simpsons", "jetsons", "flintstones" ) {
     %members = get_family($group);
     $HoH{$group} = { %members };
 }
\end{verbatim}
\begin{verbatim}
 # append new members to an existing family
 %new_folks = (
     wife => "wilma",
     pet  => "dino",
 );
\end{verbatim}
\begin{verbatim}
 for $what (keys %new_folks) {
     $HoH{flintstones}{$what} = $new_folks{$what};
 }
\end{verbatim}
\subsection*{Access and Printing of a HASH OF HASHES\label{Access_and_Printing_of_a_HASH_OF_HASHES}\index{access and printing of a hash of hashes}}
\begin{verbatim}
 # one element
 $HoH{flintstones}{wife} = "wilma";
\end{verbatim}
\begin{verbatim}
 # another element
 $HoH{simpsons}{lead} =~ s/(\w)/\u$1/;
\end{verbatim}
\begin{verbatim}
 # print the whole thing
 foreach $family ( keys %HoH ) {
     print "$family: { ";
     for $role ( keys %{ $HoH{$family} } ) {
         print "$role=$HoH{$family}{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing  somewhat sorted
 foreach $family ( sort keys %HoH ) {
     print "$family: { ";
     for $role ( sort keys %{ $HoH{$family} } ) {
         print "$role=$HoH{$family}{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\begin{verbatim}
 # print the whole thing sorted by number of members
 foreach $family ( sort { keys %{$HoH{$b}} <=> keys %{$HoH{$a}} } keys %HoH ) {
     print "$family: { ";
     for $role ( sort keys %{ $HoH{$family} } ) {
         print "$role=$HoH{$family}{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\begin{verbatim}
 # establish a sort order (rank) for each role
 $i = 0;
 for ( qw(lead wife son daughter pal pet) ) { $rank{$_} = ++$i }
\end{verbatim}
\begin{verbatim}
 # now print the whole thing sorted by number of members
 foreach $family ( sort { keys %{ $HoH{$b} } <=> keys %{ $HoH{$a} } } keys %HoH ) {
     print "$family: { ";
     # and print these according to rank order
     for $role ( sort { $rank{$a} <=> $rank{$b} }  keys %{ $HoH{$family} } ) {
         print "$role=$HoH{$family}{$role} ";
     }
     print "}\n";
 }
\end{verbatim}
\section{MORE ELABORATE RECORDS\label{MORE_ELABORATE_RECORDS}\index{MORE ELABORATE RECORDS}}
\subsection*{Declaration of MORE ELABORATE RECORDS\label{Declaration_of_MORE_ELABORATE_RECORDS}\index{declaration of more elaborate records}}


Here's a sample showing how to create and use a record whose fields are of
many different sorts:

\begin{verbatim}
     $rec = {
         TEXT      => $string,
         SEQUENCE  => [ @old_values ],
         LOOKUP    => { %some_table },
         THATCODE  => \&some_function,
         THISCODE  => sub { $_[0] ** $_[1] },
         HANDLE    => \*STDOUT,
     };
\end{verbatim}
\begin{verbatim}
     print $rec->{TEXT};
\end{verbatim}
\begin{verbatim}
     print $rec->{SEQUENCE}[0];
     $last = pop @ { $rec->{SEQUENCE} };
\end{verbatim}
\begin{verbatim}
     print $rec->{LOOKUP}{"key"};
     ($first_k, $first_v) = each %{ $rec->{LOOKUP} };
\end{verbatim}
\begin{verbatim}
     $answer = $rec->{THATCODE}->($arg);
     $answer = $rec->{THISCODE}->($arg1, $arg2);
\end{verbatim}
\begin{verbatim}
     # careful of extra block braces on fh ref
     print { $rec->{HANDLE} } "a string\n";
\end{verbatim}
\begin{verbatim}
     use FileHandle;
     $rec->{HANDLE}->autoflush(1);
     $rec->{HANDLE}->print(" a string\n");
\end{verbatim}
\subsection*{Declaration of a HASH OF COMPLEX RECORDS\label{Declaration_of_a_HASH_OF_COMPLEX_RECORDS}\index{declaration of a hash of complex records}}
\begin{verbatim}
     %TV = (
        flintstones => {
            series   => "flintstones",
            nights   => [ qw(monday thursday friday) ],
            members  => [
                { name => "fred",    role => "lead", age  => 36, },
                { name => "wilma",   role => "wife", age  => 31, },
                { name => "pebbles", role => "kid",  age  =>  4, },
            ],
        },
\end{verbatim}
\begin{verbatim}
        jetsons     => {
            series   => "jetsons",
            nights   => [ qw(wednesday saturday) ],
            members  => [
                { name => "george",  role => "lead", age  => 41, },
                { name => "jane",    role => "wife", age  => 39, },
                { name => "elroy",   role => "kid",  age  =>  9, },
            ],
         },
\end{verbatim}
\begin{verbatim}
        simpsons    => {
            series   => "simpsons",
            nights   => [ qw(monday) ],
            members  => [
                { name => "homer", role => "lead", age  => 34, },
                { name => "marge", role => "wife", age => 37, },
                { name => "bart",  role => "kid",  age  =>  11, },
            ],
         },
      );
\end{verbatim}
\subsection*{Generation of a HASH OF COMPLEX RECORDS\label{Generation_of_a_HASH_OF_COMPLEX_RECORDS}\index{generation of a hash of complex records}}
\begin{verbatim}
     # reading from file
     # this is most easily done by having the file itself be
     # in the raw data format as shown above.  perl is happy
     # to parse complex data structures if declared as data, so
     # sometimes it's easiest to do that
\end{verbatim}
\begin{verbatim}
     # here's a piece by piece build up
     $rec = {};
     $rec->{series} = "flintstones";
     $rec->{nights} = [ find_days() ];
\end{verbatim}
\begin{verbatim}
     @members = ();
     # assume this file in field=value syntax
     while (<>) {
         %fields = split /[\s=]+/;
         push @members, { %fields };
     }
     $rec->{members} = [ @members ];
\end{verbatim}
\begin{verbatim}
     # now remember the whole thing
     $TV{ $rec->{series} } = $rec;
\end{verbatim}
\begin{verbatim}
     ###########################################################
     # now, you might want to make interesting extra fields that
     # include pointers back into the same data structure so if
     # change one piece, it changes everywhere, like for example
     # if you wanted a {kids} field that was a reference
     # to an array of the kids' records without having duplicate
     # records and thus update problems.
     ###########################################################
     foreach $family (keys %TV) {
         $rec = $TV{$family}; # temp pointer
         @kids = ();
         for $person ( @{ $rec->{members} } ) {
             if ($person->{role} =~ /kid|son|daughter/) {
                 push @kids, $person;
             }
         }
         # REMEMBER: $rec and $TV{$family} point to same data!!
         $rec->{kids} = [ @kids ];
     }
\end{verbatim}
\begin{verbatim}
     # you copied the array, but the array itself contains pointers
     # to uncopied objects. this means that if you make bart get
     # older via
\end{verbatim}
\begin{verbatim}
     $TV{simpsons}{kids}[0]{age}++;
\end{verbatim}
\begin{verbatim}
     # then this would also change in
     print $TV{simpsons}{members}[2]{age};
\end{verbatim}
\begin{verbatim}
     # because $TV{simpsons}{kids}[0] and $TV{simpsons}{members}[2]
     # both point to the same underlying anonymous hash table
\end{verbatim}
\begin{verbatim}
     # print the whole thing
     foreach $family ( keys %TV ) {
         print "the $family";
         print " is on during @{ $TV{$family}{nights} }\n";
         print "its members are:\n";
         for $who ( @{ $TV{$family}{members} } ) {
             print " $who->{name} ($who->{role}), age $who->{age}\n";
         }
         print "it turns out that $TV{$family}{lead} has ";
         print scalar ( @{ $TV{$family}{kids} } ), " kids named ";
         print join (", ", map { $_->{name} } @{ $TV{$family}{kids} } );
         print "\n";
     }
\end{verbatim}
\section{Database Ties\label{Database_Ties}\index{database ties}}


You cannot easily tie a multilevel data structure (such as a hash of
hashes) to a dbm file.  The first problem is that all but GDBM and
Berkeley DB have size limitations, but beyond that, you also have problems
with how references are to be represented on disk.  One experimental
module that does partially attempt to address this need is the MLDBM
module.  Check your nearest CPAN site as described in \emph{perlmodlib} for
source code to MLDBM.

\section{SEE ALSO\label{SEE_ALSO-perldsc}}


perlref(1), perllol(1), perldata(1), perlobj(1)

\section{AUTHOR\label{AUTHOR-perldsc}}


Tom Christiansen $<$\emph{tchrist@perl.com}$>$



Last update:
Wed Oct 23 04:57:50 MET DST 1996

